plugins {
    id 'buildlogic.java-application-conventions'
    id 'com.palantir.git-version' version '4.0.0'
}

group 'org.egothor'
version gitVersion(prefix:'release@')

dependencies {
    implementation 'org.apache.commons:commons-text'
    implementation 'commons-cli:commons-cli'
    implementation project(':lib')
	// might be removed if I move BC ops to the lib
	testImplementation 'org.bouncycastle:bcpkix-jdk18on'
}

application {
    // Define the main class for the application.
    mainClass = 'zeroecho.ZeroEcho'
}

jar {
	manifest {
		attributes(
			'Main-Class': application.mainClass,
			'Implementation-Title': rootProject.name,
			'Implementation-Version': "${version}"
		)
	}
	
	// Include compiled classes from main source set
	from sourceSets.main.output
		
	dependsOn configurations.runtimeClasspath
	from {
        configurations.runtimeClasspath.collect { dep ->
            if (dep.isDirectory()) {
                dep
            } else {
                zipTree(dep).matching {
                    exclude 'META-INF/LICENSE.*'
                    exclude 'META-INF/*.SF'
                    exclude 'META-INF/*.DSA'
                    exclude 'META-INF/*.RSA'
                }
            }
        }
    }

    duplicatesStrategy = DuplicatesStrategy.EXCLUDE

}